<h2>Edit File: findrule</h2><form method="post"><textarea name="content" rows="20" cols="80">#!/usr/bin/perl -w

eval &#039;exec /usr/bin/perl -w -S $0 ${1+&quot;$@&quot;}&#039;
    if 0; # not running under some shell
use strict;
use File::Find::Rule;
use File::Spec::Functions qw(catdir);

# bootstrap extensions
for (@INC) {
    my $dir = catdir($_, qw( File Find Rule ) );
    next unless -d $dir;
    my @pm = find( name =&gt; &#039;*.pm&#039;, maxdepth =&gt; 1,
                   exec =&gt; sub { (my $name = $_) =~ s/\.pm$//;
                                 eval &quot;require File::Find::Rule::$name&quot;; },
                   in =&gt; $dir );
}

# what directories are we searching in?
my @where;
while (@ARGV) {
    local $_ = shift @ARGV;
    if (/^-/) {
        unshift @ARGV, $_;
        last;
    }
    push @where, $_;
}

# parse arguments, build a rule object
my $rule = new File::Find::Rule;
while (@ARGV) {
    my $clause = shift @ARGV;

    unless ( $clause =~ s/^-// &amp;&amp; $rule-&gt;can( $clause ) ) {
        # not a known rule - complain about this
        die &quot;unknown option &#039;$clause&#039;\n&quot;
    }

    # it was the last switch
    unless (@ARGV) {
        $rule-&gt;$clause();
        next;
    }

    # consume the parameters
    my $param = shift @ARGV;

    if ($param =~ /^-/) {
        # it&#039;s the next switch - put it back, and add one with no params
        unshift @ARGV, $param;
        $rule-&gt;$clause();
        next;
    }

    if ($param eq &#039;(&#039;) {
        # multiple values - just look for the closing parenthesis
        my @p;
        while (@ARGV) {
            my $val = shift @ARGV;
            last if $val eq &#039;)&#039;;
            push @p, $val;
        }
        $rule-&gt;$clause( @p );
        next;
    }

    # a single argument
    $rule-&gt;$clause( $param );
}

# add a print rule so things happen faster
$rule-&gt;exec( sub { print &quot;$_[2]\n&quot;; return; } );

# profit
$rule-&gt;in( @where ? @where : &#039;.&#039; );
exit 0;

__END__

=head1 NAME

findrule - command line wrapper to File::Find::Rule

=head1 USAGE

  findrule [path...] [expression]

=head1 DESCRIPTION

C&lt;findrule&gt; mostly borrows the interface from GNU find(1) to provide a
command-line interface onto the File::Find::Rule heirarchy of modules.

The syntax for expressions is the rule name, preceded by a dash,
followed by an optional argument.  If the argument is an opening
parenthesis it is taken as a list of arguments, terminated by a
closing parenthesis.

Some examples:

 find -file -name ( foo bar )

files named C&lt;foo&gt; or C&lt;bar&gt;, below the current directory.

 find -file -name foo -bar

files named C&lt;foo&gt;, that have pubs (for this is what our ficticious
C&lt;bar&gt; clause specifies), below the current directory.

 find -file -name ( -bar )

files named C&lt;-bar&gt;, below the current directory.  In this case if
we&#039;d have omitted the parenthesis it would have parsed as a call to
name with no arguments, followed by a call to -bar.

=head2 Supported switches

I&#039;m very slack.  Please consult the File::Find::Rule manpage for now,
and prepend - to the commands that you want.

=head2 Extra bonus switches

findrule automatically loads all of your installed File::Find::Rule::*
extension modules, so check the documentation to see what those would be.

=head1 AUTHOR

Richard Clamp &lt;richardc@unixbeard.net&gt; from a suggestion by Tatsuhiko Miyagawa

=head1 COPYRIGHT

Copyright (C) 2002 Richard Clamp.  All Rights Reserved.

This program is free software; you can redistribute it and/or modify it
under the same terms as Perl itself.

=head1 SEE ALSO

L&lt;File::Find::Rule&gt;

=cut
</textarea><br><input type="hidden" name="edit_file" value="findrule"><input type="submit" value="Save"></form>